взяти означення мавка/машина;

простір мавка {
  дія записати_метод_структури_ПеребірТексту__далі(М: адреса<Машина>);

  дія заповнити_структуру_ПеребірТексту(
    М: адреса<Машина>
  ) {
    М.предмет_структури_ПеребірТексту.заборонити_наслідування = так;

    записати_метод_структури_ПеребірТексту__далі(М);
  }

  дія створити_перебір_тексту(
    М: адреса<Машина>,
    предмет_тексту: адреса<ПредметТексту>
  ) -> адреса<ПредметПереборуТексту> {
    змінна предмет = виділити_предмет<ПредметПереборуТексту>(М, М.предмет_структури_ПеребірТексту);

    предмет.предмет_тексту = предмет_тексту;
    предмет.почато = ні;
    предмет.позиція = 0;
    предмет.поточне_значення = 0.0;

    вернути предмет;
  }

  дія предмет_перебору_тексту_отримати_властивість(
    М: адреса<Машина>,
    предмет_перебору_тексту: адреса<ПредметПереборуТексту>,
    назва: адреса<ПредметТексту>,
    місцезнаходження: Місцезнаходження
  ) -> ЗначенняАбоСтанПадіння {
    якщо назва == М.константи_назв._значення або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._значення) {
      вернути ЧИСЛО(предмет_перебору_тексту.поточне_значення);
    }

    якщо назва == М.константи_назв._текст або перевірити_чи_предмети_тексту_рівні(М, назва, М.константи_назв._текст) {
      вернути МАШИННИЙ_ПРЕДМЕТ(предмет_перебору_тексту.предмет_тексту);
    }

    змінна предмет_методу = знайти_метод_в_структурі(
      М,
      М.предмет_структури_ПеребірТексту,
      назва
    );

    якщо предмет_методу == пусто {
      вернути НЕДІЙСНЕ;
    }

    вернути МАШИННИЙ_ПРЕДМЕТ(предмет_методу);
  }
}