взяти означення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_метода_структури_ПеребірСписку__далі(
    М: адреса<Машина>,
    діяльність: адреса<Діяльність>
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗМашиннийПредмет і діяльність.здійснювач.вид != ЗСкладенийПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору списку \"далі\"."));
    }

    змінна предмет_перебору_списку = діяльність.здійснювач.дані як адреса<Предмет> як адреса<ПредметПереборуСписку>;

    якщо предмет_перебору_списку.тип != М.предмет_структури_ПеребірСписку {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору списку \"далі\"."));
    }

    якщо предмет_перебору_списку.почато {
      предмет_перебору_списку.позиція += 1;
    } інакше {
      предмет_перебору_списку.позиція = 0;
      предмет_перебору_списку.почато = так;
    }

    якщо предмет_перебору_списку.позиція < предмет_перебору_списку.предмет_списку.розмір {
      предмет_перебору_списку.поточне_значення = предмет_перебору_списку.предмет_списку.елементи[предмет_перебору_списку.позиція];

      вернути ДІЙСНЕ;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_структури_ПеребірСписку__далі(
    М: адреса<Машина>
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._далі,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_метода_структури_ПеребірСписку__далі,
      пусто
    );

    записати_метод_структури(
      М,
      М.предмет_структури_ПеребірСписку,
      М.константи_назв._далі,
      предмет_дії
    );
  }
}