взяти означення мавка/машина;

простір мавка {
  внутрішня дія рідна_дія_метода_структури_ПеребірДаних__далі(
    М: адреса<Машина>,
    діяльність: адреса<Діяльність>
  ) -> ЗначенняАбоСтанПадіння {
    якщо діяльність.здійснювач.вид != ЗМашиннийПредмет і діяльність.здійснювач.вид != ЗСкладенийПредмет {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору даних \"далі\"."));
    }

    змінна предмет_перебору_даних = діяльність.здійснювач.дані як адреса<Предмет> як адреса<ПредметПереборуДаних>;

    якщо предмет_перебору_даних.тип != М.предмет_структури_ПеребірДаних {
      вернути ПАДІННЯ(М, створити_текст(М, "Неможливо здійснити дію перебору даних \"далі\"."));
    }

    якщо предмет_перебору_даних.почато {
      предмет_перебору_даних.позиція += 1;
    } інакше {
      предмет_перебору_даних.позиція = 0;
      предмет_перебору_даних.почато = так;
    }

    якщо предмет_перебору_даних.позиція < предмет_перебору_даних.предмет_даних.розмір {
      предмет_перебору_даних.поточне_значення = д64(предмет_перебору_даних.предмет_даних.дані[предмет_перебору_даних.позиція]);

      вернути ДІЙСНЕ;
    }

    вернути НЕДІЙСНЕ;
  }

  дія записати_метод_структури_ПеребірДаних__далі(
    М: адреса<Машина>
  ) {
    змінна предмет_дії = створити_рідну_дію(
      М,
      М.константи_назв._далі,
      М.предмет_пустої_послідовності,
      пусто,
      рідна_дія_метода_структури_ПеребірДаних__далі,
      пусто
    );

    записати_метод_структури(
      М,
      М.предмет_структури_ПеребірДаних,
      М.константи_назв._далі,
      предмет_дії
    );
  }
}